IEstimateFactory Interface

' The following code will inspect specified estimate. We don't want to modify the estimate,
 ' we only need to read some info from it. In such a case it is safer to open it in "read-only" mode.
 ' This is done by creating a tmp copy of the file and working with it.
 ' The file name of the estimate to be inspected.
 
 Dim estimateFileName As String = "C:\Sample_1.qdv"
 Dim estimate As IEstimate = Nothing
 
 ' Use IQdvEnvironment to get a tmp path.
 Dim tmpFileName As String = Context.QdvManager.Environment.GetQdvTempFileName(".qdv", "readonly_copy_")
 ' The tmpFileName is something like C:\Users\<USER>\AppData\Local\Temp\QDVTempFilesMain\readonly_copy_kqcc1fp5.qdv.
 
 Try
 
  ' Create a tmp copy of the estimate file. This will prevent from any changes in the original file
  ' and more importantly, it prevents problems if the estimate is already opened (and thus locked).
  If System.IO.File.Exists(estimateFileName) Then
   System.IO.File.Copy(estimateFileName, tmpFileName, True)
  End If
  
  ' Remove the read-only protection, if it was applied. Can happen if the original file had the read-only attribute.
  Dim attributes As System.IO.FileAttributes = System.IO.File.GetAttributes(tmpFileName)
  attributes = attributes And Not System.IO.FileAttributes.ReadOnly
  System.IO.File.SetAttributes(tmpFileName, attributes)
  
  ' Get the estimate instance with IEstimateFactory.
  estimate = Context.QdvManager.EstimateFactory.GetEstimate(tmpFileName)
  
  ' Get required data from the estimate. For example, get the number of all tasks.
  Dim taskCount As Integer = estimate.CurrentVersion.Wbs.GetTasksForScope("", True).Count
  MessageBox.Show("The number of tasks in the inspected estimate is " & taskCount)
  
 Finally
 
  ' When everything is done, don't forget to close the estimate.
  If estimate IsNot Nothing Then
   estimate.Close()
  End If
  ' There's no need to delete the tmp file created with GetQdvTempFileName
  ' because it is done automatically when QDV application is closed.
  
 End Try